<xsl:when>  
<xsl:choose> 要素の分岐を 1 つ定義します。これは、Java の case ステートメントに相当します。
 
カテゴリ

サブ命令 (<xsl:when> は <xsl:choose> 要素の子として指定する必要があります)。
 
必須の属性
test
評価されるブール式を含みます。式により true と評価されると、 < xsl:when > 要素のコンテンツが処理されます。それ以外の場合、 < xsl:when > のコンテンツは無視されます。

 
省略可能な属性

なし。
 
コンテンツ

XSLT テンプレート。
 
指定先

<xsl:choose> 要素のみ。

 
定義先

XSLT 9.2 節「xsl:choose による条件処理」
 
例

この例では、1 つの <xsl:choose> 要素と 3 つの <xsl:when> 要素を使用して一連の値を分岐させています。各 <listitem> に対して、HTML テーブルの行を生成します。

<?xml version="1.0"?>
<list xml:lang="en">
  <title>Albums I've bought recently:</title>
  <listitem>The Sacred Art of Dub</listitem>
  <listitem>Only the Poor Man Feel It</listitem>
  <listitem>Excitable Boy</listitem>
  <listitem xml:lang="sw">Aki Special</listitem>
  <listitem xml:lang="en-gb">Combat Rock</listitem>
  <listitem xml:lang="zu">Talking Timbuktu</listitem>
  <listitem xml:lang="jz">The Birth of the Cool</listitem>
</list>

スタイルシートにより、mintcream、lavender、whitesmoke、および papayawhip の背景色が指定されたテーブルの行が生成されます。ソースドキュメントの各 <listitem> に対して、いずれかの <xsl:when> 要素 (または <xsl:otherwise> 要素) により適切な色が生成されます。

<?xml version="1.0"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">


  <xsl:output method="html"/>

  <xsl:template match="/">
    <html>
      <head>
        <title>
          <xsl:value-of select="list/title"/>
        </title>
      </head>
      <body>
        <h1><xsl:value-of select="list/title"/></h1>
        <table border="1">
          <xsl:for-each select="list/listitem">
            <tr>
              <td>
                <xsl:attribute name="bgcolor">
                  <xsl:choose>
                    <xsl:when test="@bgcolor">
                      <xsl:value-of select="@bgcolor"/>
                    </xsl:when>
                    <xsl:when test="position() mod 4 = 0">
                      <xsl:text>papayawhip</xsl:text>
                    </xsl:when>
                    <xsl:when test="position() mod 4 = 1">
                      <xsl:text>mintcream</xsl:text>
                    </xsl:when>
                    <xsl:when test="position() mod 4 = 2">
                      <xsl:text>lavender</xsl:text>
                    </xsl:when>
                    <xsl:otherwise>
                      <xsl:text>whitesmoke</xsl:text>
                    </xsl:otherwise>
                  </xsl:choose>
                </xsl:attribute>
                <xsl:value-of select="."/>
              </td>
            </tr>
          </xsl:for-each>
        </table>
      </body>
    </html>
  </xsl:template>

</xsl:stylesheet>

このスタイルシートを使用して XML ソースドキュメントを処理した結果は次のとおりです。

<html>
<head>
<META http-equiv="Content-Type" content="text/html; charset=UTF-8">
<title>Albums I've bought recently:</title>
</head>
<body>
<h1>Albums I've bought recently:</h1>
<table border="1">
<tr>
<td bgcolor="mintcream">The Sacred Art of Dub</td>
</tr>
<tr>
<td bgcolor="lavender">Only the Poor Man Feel It</td>
</tr>
<tr>
<td bgcolor="whitesmoke">Excitable Boy</td>
</tr>
<tr>
<td bgcolor="papayawhip">Aki Special</td>
</tr>
<tr>
<td bgcolor="mintcream">Combat Rock</td>
</tr>
<tr>
<td bgcolor="lavender">Talking Timbuktu</td>
</tr>
<tr>
<td bgcolor="whitesmoke">The Birth of the Cool</td>
</tr>
</table>
</body>
</html>

papayawhip、mintcream、または lavender の背景色が指定されたすべての <td> 要素は、いずれかの <xsl:when> 要素によって生成されます。