<xsl:message>  
メッセージを送信します。メッセージの送信方法は XSLT プロセッサによって異なりますが、通常、メッセージは標準の出力デバイスに書き込まれます。この要素は、スタイルシートのデバッグに便利です。
 
カテゴリ

命令
 
必須の属性

なし。
 
省略可能な属性
terminate= " yes " | " no "
この属性の値が yes である場合は、このメッセージの発行後に XSLT プロセッサが処理を終了します。この属性の既定値は、 no です。 < xsl:message > によりプロセッサの処理が終了しない場合は、メッセージが送信され処理が続行します。

 
コンテンツ

XSLT テンプレート。
 
指定先

<xsl:message> はテンプレート内に表示されます。

 
定義先

XSLT 13 節「メッセージ」
 
例

次のスタイルシートは、<xsl:message> 要素を使用して XML ドキュメントの変換をトレースします。最近購入したアルバムのリストを再び使用します。

<?xml version="1.0"?>
<list xml:lang="en">
  <title>Albums I've bought recently:</title>
  <listitem>The Sacred Art of Dub</listitem>
  <listitem>Only the Poor Man Feel It</listitem>
  <listitem>Excitable Boy</listitem>
  <listitem xml:lang="sw">Aki Special</listitem>
  <listitem xml:lang="en-gb">Combat Rock</listitem>
  <listitem xml:lang="zu">Talking Timbuktu</listitem>
  <listitem xml:lang="jz">The Birth of the Cool</listitem>
</list>

購入したすべてのアルバムの一覧を HTML テーブルに表示します。各行の背景色が交互に変化します。このスタイルシートでは、<xsl:attribute> 要素内に <xsl:choose> 要素を使用して bgcolor 属性の値を決定します。指定した <listitem> が、背景色が lavender の HTML の <tr> に変換された場合は、それを発表するメッセージが発行されます。

<?xml version="1.0"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

  <xsl:output method="html"/>

  <xsl:template match="/">
    <html>
      <head>
        <title>
          <xsl:value-of select="list/title"/>
        </title>
      </head>
      <body>
        <h1><xsl:value-of select="list/title"/></h1>
        <table border="1">
          <xsl:for-each select="list/listitem">
            <tr>
              <td>
                <xsl:attribute name="bgcolor">
                  <xsl:choose>
                    <xsl:when test="position() mod 4 = 0">
                      <xsl:text>papayawhip</xsl:text>
                    </xsl:when>
                    <xsl:when test="position() mod 4 = 1">
                      <xsl:text>mintcream</xsl:text>
                    </xsl:when>
                    <xsl:when test="position() mod 4 = 2">
                      <xsl:text>lavender</xsl:text>
                      <xsl:message terminate="no">
                        <xsl:text>Table row #</xsl:text>
                        <xsl:value-of select="position()"/>
                        <xsl:text> is lavender!</xsl:text>
                      </xsl:message>
                    </xsl:when>
                    <xsl:otherwise>
                      <xsl:text>whitesmoke</xsl:text>
                    </xsl:otherwise>
                  </xsl:choose>
                </xsl:attribute>
                <xsl:value-of select="."/>
              </td>
            </tr>
          </xsl:for-each>
        </table>
      </body>
    </html>
  </xsl:template>

</xsl:stylesheet>

XSLT の仕様では、メッセージの発行方法が定義されません。このスタイルシートを Xalan 2.0.1 で使用すると、次の結果が得られます。

file:///D:/O'Reilly/XSLT/bookSamples/AppendixA/message.xsl; Line 32; Column 51;
Table row #2 is lavender!
file:///D:/O'Reilly/XSLT/bookSamples/AppendixA/message.xsl; Line 32; Column 51;
Table row #6 is lavender!

Xalan では、各メッセージを生成したスタイルシートの部分に関するフィードバックが提供されます。一方 Saxon では、次のようにメッセージのみ表示されます。

Table row #2 is lavender!
Table row #6 is lavender!

その他の例として、XT が <xsl:message> 要素を処理する方法を次に示します。

file:/D:/O'Reilly/XSLT/bookSamples/AppendixA/test4.xml:5: Table row #2 is lavender!
file:/D:/O'Reilly/XSLT/bookSamples/AppendixA/test4.xml:9: Table row #6 is lavender!

XT では、メッセージを生成した XML ソースドキュメントの行に関する情報が提供されます。