<xsl:choose>  
<xsl:choose> 要素は、多くのプロシージャプログラミング言語に見られる switch または case ステートメントの XSLT バージョンです。
 
カテゴリ

命令
 
必須の属性

なし。
 
省略可能な属性

なし。
 
コンテンツ

1 つまたは複数の <xsl:when> 要素を含みます。また 1 つの <xsl:otherwise> 要素を含むことがあります。<xsl:otherwise> 要素は、<xsl:choose> 内の最後の要素である必要があります。
 
指定先

<xsl:choose> はテンプレート内に指定します。

 
定義先

XSLT 9.2 節「xsl:choose による条件処理」
 
例

<xsl:choose> を使用して、HTML テーブルの行の背景色を選択する例を次に示します。4 つの異なる色を順に設定し、<xsl:choose> を使用して、生成された HTML ドキュメントの bgcolor 属性の値を指定します。使用する XML ドキュメントは次のとおりです。

<?xml version="1.0"?>
<list xml:lang="en">
  <title>Albums I've bought recently:</title>
  <listitem>The Sacred Art of Dub</listitem>
  <listitem>Only the Poor Man Feel It</listitem>
  <listitem>Excitable Boy</listitem>
  <listitem xml:lang="sw">Aki Special</listitem>
  <listitem xml:lang="en-gb">Combat Rock</listitem>
  <listitem xml:lang="zu">Talking Timbuktu</listitem>
  <listitem xml:lang="jz">The Birth of the Cool</listitem>
</list>

スタイルシートは次のとおりです。

<?xml version="1.0"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

  <xsl:output method="html"/>
 
  <xsl:template match="/">
    <html>
      <head>
        <title>
          <xsl:value-of select="list/title"/>
        </title>
      </head>
      <body>
        <h1><xsl:value-of select="list/title"/></h1>
        <table border="1">
          <xsl:for-each select="list/listitem">
            <tr>
              <td>
                <xsl:attribute name="bgcolor">
                  <xsl:choose>
                    <xsl:when test="position() mod 4 = 0">
                      <xsl:text>papayawhip</xsl:text>
                    </xsl:when>
                    <xsl:when test="position() mod 4 = 1">
                      <xsl:text>mintcream</xsl:text>
                    </xsl:when>
                    <xsl:when test="position() mod 4 = 2">
                      <xsl:text>lavender</xsl:text>
                    </xsl:when>
                    <xsl:otherwise>
                      <xsl:text>whitesmoke</xsl:text>
                    </xsl:otherwise>
                  </xsl:choose>
                </xsl:attribute>
                <xsl:value-of select="."/>
              </td>
            </tr>
          </xsl:for-each>
        </table>
      </body>
    </html>
  </xsl:template>

</xsl:stylesheet>

<xsl:choose> を使用して、生成された各 <td> 要素の背景色を指定します。生成された HTML ドキュメントを次に示します。このドキュメントは、さまざまな背景色に順次切り替わります。

<html>
<head>
<META http-equiv="Content-Type" content="text/html; charset=UTF-8">
<title>Albums I've bought recently:</title>
</head>
<body>
<h1>Albums I've bought recently:</h1>
<table border="1">
<tr>
<td bgcolor="mintcream">The Sacred Art of Dub</td>
</tr>
<tr>
<td bgcolor="lavender">Only the Poor Man Feel It</td>
</tr>
<tr>
<td bgcolor="whitesmoke">Excitable Boy</td>
</tr>
<tr>
<td bgcolor="papayawhip">Aki Special</td>
</tr>
<tr>
<td bgcolor="mintcream">Combat Rock</td>
</tr>
<tr>
<td bgcolor="lavender">Talking Timbuktu</td>
</tr>
<tr>
<td bgcolor="whitesmoke">The Birth of the Cool</td>
</tr>
</table>
</body>
</html>

この HTML ドキュメントの表示を図 A-5 に示します。

異なる背景色に順次切り替わるドキュメント