<xsl:attribute>  
出力ドキュメントで属性を作成できます。<xsl:attribute> の利点は、入力ドキュメントの部分、ハードコードされたテキスト、関数から返された値、およびスタイルシートからアクセスできるその他の値から、属性の値を作成できることにあります。
 
カテゴリ

命令
 
必須の属性
name
name 属性は、 < xsl:attribute > 要素によって作成された属性の名前を定義します。 < xsl:attribute > 要素の属性に関することは、どのように説明してもやや複雑です。

 
省略可能な属性
namespace
namespace 属性は、出力ドキュメントでこの属性に使用する名前空間 URI を定義します。使用される名前空間の接頭辞を制御する必要はありません。 namespace 属性を使用して指定する必要があるのは、名前空間の URI だけです。

 
コンテンツ

XSLT テンプレート。つまり、<xsl:choose> 要素、<xsl:text> 要素、および <xsl:value-of> 要素を使用して、属性のコンテンツを作成できます。

 
指定先

<xsl:attribute> はテンプレート内に指定します。
 
定義先

XSLT 7.1.3 節「Creating Attributes with xsl:attribute」
 
例

この例では、次の XML ドキュメントから HTML テーブルを作成します。

<?xml version="1.0"?>
<list xml:lang="en">
  <title>Albums I've bought recently:</title>
  <listitem>The Sacred Art of Dub</listitem>
  <listitem>Only the Poor Man Feel It</listitem>
  <listitem>Excitable Boy</listitem>
  <listitem xml:lang="sw">Aki Special</listitem>
  <listitem xml:lang="en-gb">Combat Rock</listitem>
  <listitem xml:lang="zu">Talking Timbuktu</listitem>
  <listitem xml:lang="jz">The Birth of the Cool</listitem>
</list>

各 <listitem> がテーブルの右の列で別の行にあり、rowspan が左の XML ドキュメントの <listitem> 要素の数と等しい 1 つのセルを持つテーブルを作成します。<listitem> の数は変更することがあるので、rowspan 属性の値をハードコードすることはできません。このスタイルシートは、<xsl:attribute> を使用して目的の処理を行います。

<?xml version="1.0"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

  <xsl:output method="html"/>

  <xsl:template match="/">
    <html>
      <head>
        <title><xsl:value-of select="list/title"/></title>
      </head>
      <body>
        <xsl:apply-templates select="list"/>
      </body>
    </html>
  </xsl:template>

  <xsl:template match="list">
    <table border="1" width="75%">
      <tr>
        <td bgcolor="lightslategray" width="100" align="right">
          <xsl:attribute name="rowspan">
            <xsl:value-of select="count(listitem)"/>
          </xsl:attribute>
          <p style="font-size: 125%">
            <xsl:value-of select="title"/>
          </p>
        </td>
        <td>
          <xsl:value-of select="listitem[1]"/>
        </td>
      </tr>
      <xsl:for-each select="listitem">
        <xsl:if test="position() > 1">
          <tr>
            <td>
              <xsl:value-of select="."/>
            </td>
          </tr>
        </xsl:if>
      </xsl:for-each>
    </table>
  </xsl:template>

</xsl:stylesheet>

生成された HTML ドキュメントは次のとおりです。

<html>
<head>
<META http-equiv="Content-Type" content="text/html; charset=UTF-8">
<title>Albums I've bought recently:</title>
</head>
<body>
<table width="75%" border="1">
<tr>
<td align="right" width="100" rowspan="7" bgcolor="lightslategray">
<p style="font-size: 125%">Albums I've bought recently:</p>
</td><td>The Sacred Art of Dub</td>
</tr>
<tr>
<td>Only the Poor Man Feel It</td>
</tr>
<tr>
<td>Excitable Boy</td>
</tr>
<tr>
<td>Aki Special</td>
</tr>
<tr>
<td>Combat Rock</td>
</tr>
<tr>
<td>Talking Timbuktu</td>
</tr>
<tr>
<td>The Birth of the Cool</td>
</tr>
</table>
</body>
</html>

<td> 要素ではいくつかの属性がハードコードされていました。これらの属性は、<xsl:attribute> を使用して作成した属性と組み合わせられます。必要に応じてどれだけでも <xsl:attribute> 要素を作成できますが、それらは、属性の追加先となる要素内で、先頭にまとめて表示される必要があります。図 A-3 に、生成した HTML ドキュメントの外観を示します。

生成された属性を持つドキュメント

このインスタンスでは、属性値テンプレートを使用することができました。次のような rowspan 属性の値を生成できます。

<td bgcolor="lightslategray" rowspan="{count(listitem)}"
  width="100" align="right">

中かっこ ({}) 内の式が評価され、その値で置き換えられます。この場合、count(listitem) は数値 7 を返しますが、これは rowspan 属性の値になります。