| CFFORMGROUP | |||
| 説明
複数のフォームコントロール用のコンテナコントロールを作成します。Macromedia Flash フォームおよび XML フォームの cfform タグ本文で使用します。HTML フォームでは無視されます。 |
|||
| カテゴリ
フォームタグ | |||
シンタックス<cfformgroup type = "group type" label = "label" style = "style specification" selectedIndex = "page number"> width = "pixels" height = "pixels" enabled = "Yes"、"No" visible = "Yes"、"No" OnChange = "ActionScript expression" toolTip = "Tip text" ...ColdFusion フォームコントロール </cfformgroup> または <cfformgroup type = "repeater" query = "query object" startrow = "row number" maxrows = "integer"> ...ColdFusion フォームコントロール </cfformgroup> |
|||
| 関連項目
cfapplet、cfcalendar、cfform、cfformitem、cfgrid、cfinput、cfselect、cfslider、cftextarea、cftree、『ColdFusion MX 開発ガイド』の第29章の「Macromedia Flash 形式のフォームの作成」 の「cfformgroup タグによるフォームの構築」および第30章の「スキン可能 XML フォームの作成」 の「cfformgroup タグの使用」 |
|||
| ヒストリ
ColdFusion MX 7: このタグが追加されました。 次の表に、Flash フォームの属性とその動作を示します。XML の場合、特記なき限り、属性は XML に渡されますが、ColdFusion MX に同梱されている基本的な XSL スタイルシートでは解釈されません。
|
|||
| 使用方法
このタグには終了タグが必要です。cfform タイプが HTML の場合、このタグは無視されます。すべてのタグ本文の内容は、cfformgroup で囲まれていないかのように解釈されます。 Flash 形式のフォームでは、このタグがフォームの内容を構成します。このタグが子タグをグループ化して整列します。このタグの本文には、次のタグを含めることができます。その他のタグとテキストはすべて無視されます。
Flash フォームでのこのタグの使用方法については、『ColdFusion MX 開発ガイド』の第29章の「Macromedia Flash 形式のフォームの作成」 を参照してください。 XML 形式では、ColdFusion はこのタグとその属性を XML に渡します。XML を処理するのは、スキン XSLT です。ColdFusion の基本的なスキンは、horizontal、vertical、および dualselectlist のスタイルのみをサポートします。XML フォームでのこのタグの使用方法については、『ColdFusion MX 開発ガイド』の第29章の「Macromedia Flash 形式のフォームの作成」 を参照してください。 |
|||
| 例
単一の cfformgroup タグを使用する XML フォームの簡単な例については、cfform を参照してください。 次の例は、cfformgroup タグを使用して Flash フォームに要素を整列する方法を示しています。hdividedbox コンテナを作成します。各 hdividedbox コンテナには、vbox コンテナが 1 つ含まれています。左のボックスには、見出しテキストと 2 つのラジオボタンがあります。右のボックスには、見出しテキストと 3 つのチェックボックスがあります。 <h3>簡単な cfformgroup の例</h3>
<cfform name="myform" height="450" width="500" format="Flash" >
<cfformgroup type="hdividedbox" >
<cfformgroup type="VBox">
<cfformitem type="text" height="20">
ペット :
</cfformitem>
<cfinput type="Radio" name="pets" label="Dogs" value="Dogs"
checked>
<cfinput type="Radio" name="pets" label="Cats" value="Cats">
</cfformgroup>
<cfformgroup type="VBox">
<cfformitem type="text" height="20">
果物 :
</cfformitem>
<cfinput type = "Checkbox" name="chk1" Label="Apples"
value="Apples">
<cfinput type="Checkbox" name="chk2" Label="Bananas"
value="Bananas">
<cfinput type="Checkbox" name="chk3" Label="Pears"
value="Pears">
</cfformgroup>
</cfformgroup>
</cfform>
さらに複雑な次の例は、cfformgroup タグを使用して Flash フォームにコントロールを整列する方法をより詳細に示しています。cfformgroup の本文で使用できるテキストの書式設定機能も多数示しています。フォームを送信する際には、送信データを示すために、ページでは Forms スコープの内容をダンプします。 <h2>QueryNew の例</h2>
<cfif IsDefined("form.oncethrough")>
<h3>次の情報を ColdFusion MX に送信したフォーム :</h3>
<cfdump var="#form#"><br><br><br>
</cfif>
<h3>cfformgroup タグを使用する Flash フォーム</h3>
<cfform name="myform" height="450" width="500" format="Flash">
<!--- 次のフォームグループは書式設定されたテキストを表示する方法を示します。 --->
<cfformitem type="html">
<b><font color="#FF0000" size="+4" face="serif">
このフォームには、次の事項を確認する 2 つのタブがあります。</font></b><br>
<li>連絡先情報</li>
<li><i>嗜好</i></li>
<b>両方のタブに情報を入力してください。</b><br>
フォームを送信して、ColdFusion の Forms スコープの内容を確認してください。</b><br>
<a href="http://www.macromedia.com/" target="_blank">
<font color="#0000FF"><u>
このリンクにより、Macromedia のホームページが新しいブラウザウィンドウに表示されます。
</u></font></a><br>
<br>
</cfformitem>
<!--- 2 つのタブがある tabnavigator を使用して、ユーザー入力を行います。 --->
<cfformgroup type="tabnavigator" height="220">
<cfformgroup type="page" label="Contact Information">
<!--- 姓フィールドと名フィールドを水平方向に配置します。 --->
<cfformgroup type="horizontal" label="Your Name">
<cfinput type="text" required="Yes" name="firstName" label="First"
value="" width="100"/>
<cfinput type="text" required="Yes" name="lastName" label="Last"
value="" width="100"/>
</cfformgroup>
<cfformitem type="html"><textformat indent="95"><font size="-2">
電子メールフィールドは自動的に入力されます。
任意のテキストで置き換えることができます。
</font></textformat>
</cfformitem>
<!--- bind 属性により、firstName および lastName フィールドに
入力されたとおりのフィールドのコンテンツを取得します。 --->
<cfinput type="text" name="email" label="email"
bind="{firstName.text}.{lastName.text}@mm.com">
<cfinput type="text" name="phone" validate="telephone" required="Yes"
label="Phone Number">
</cfformgroup>
<cfformgroup type="page" label="Preferences">
<cfformitem type="text" height="30">
<b>あなたの好みをお聞かせください。</b>
</cfformitem>
<!--- ペット選択肢を果物選択肢の左に配置します。 --->
<cfformgroup type="hbox">
<!--- ペット選択肢ボックスのコンテンツをグループ化し、垂直方向に整列します。 --->
<cfformgroup type="vbox">
<cfformitem type="text" height="20">
ペット :
</cfformitem>
<cfformgroup type="vertical">
<cfinput type="Radio" name="pets" label="Dogs" value="Dogs"
checked>
<cfinput type="Radio" name="pets" label="Cats" value="Cats">
</cfformgroup>
</cfformgroup>
<!--- 果物選択肢ボックスのコンテンツをグループ化し、垂直方向に整列します。 --->
<cfformgroup type="vbox">
<cfformitem type="text" height="20">
果物 :
</cfformitem>
<cfformgroup type="tile" width="200" label="Tile box">
<--- Flash では、すべてのコントロールに対して一意の名前を設定する必要があります。 --->
<cfinput type = "Checkbox" name="chk1" Label="Apples"
value="Apples">
<cfinput type="Checkbox" name="chk2" Label="Bananas"
value="Bananas">
<cfinput type="Checkbox" name="chk3" Label="Pears"
value="Pears">
<cfinput type="Checkbox" name="chk4" Label="Oranges"
value="Oranges">
<cfinput type="Checkbox" name="chk5" Label="Grapes"
value="Grapes">
<cfinput type="Checkbox" name="chk6" Label="Cumquats"
value="Cumquats">
</cfformgroup>
</cfformgroup>
</cfformgroup>
</cfformgroup>
</cfformgroup>
<cfformgroup type="horizontal">
<cfinput type = "submit" name="submit" width="100" value = "Show Results">
<cfinput type = "reset" name="reset" width="100" value = "Reset Fields">
<cfinput type = "hidden" name="oncethrough" value = "Yes">
</cfformgroup>
</cfform>
|
|||