cfcatch タグと共に使用します。これらを併用することで、ColdFusion ページで発生する例外の検出や処理を実行します。例外は、データベースオペレーションの失敗、インクルードファイルの欠如、開発者によって指定されたイベントなど、ColdFusion ページ内での正常な命令の流れを妨げるイベントです。

例外処理タグ

cfcatch、cferror、cfrethrow、cfthrow、onError、『ColdFusion MX 開発ガイド』の第14章の「エラーの処理」

ColdFusion MX: cfscript が変更され、cftry および cfcatch タグに相当する try および catch ステートメントが含まれるようになりました。

cftry ブロック内に、例外を発生する可能性のあるコードを配置します。その後ろに、例外を検出して処理する cfcatch タグを配置します。このタグには終了タグが必要です。

<!--- TagContext を使用してタグスタックを表示する cftry の例 --->
<h3>cftry の例</h3>
<!--- cftry ブロックを開きます。 --->
<cftry>
   <!--- テーブル名 "employees" のスペルが誤って "employeeas" になっています。 --->
   <cfquery name = "TestQuery" dataSource = "cfdocexamples">
      SELECT *
      FROM EMPLOYEEAS
   </cfquery>

   <!--- <p>... 他の処理がここで行われます。 --->
   <!--- 検出するエラーのタイプを指定 --->
   <cfcatch type = "Database">
   <!--- 表示するメッセージ --->
      <h3>データベース<b>エラー</b><が発生しました。/h3>
      <cfoutput>
         <!--- ColdFusion サーバーからの診断メッセージ --->
         <p>#cfcatch.message#</p>
         <p>例外エラー、type = #CFCATCH.TYPE# を検出しました。 </p>
         <p>タグスタックの内容は次のとおりです。</p>
         <cfloop index = i from = 1
               to = #ArrayLen(CFCATCH.TAGCONTEXT)#>
            <cfset sCurrent = #CFCATCH.TAGCONTEXT[i]#>
            <br>#i# #sCurrent["ID"]# 
               (#sCurrent["LINE"]#,#sCurrent["COLUMN"]#)
               #sCurrent["TEMPLATE"]#
         </cfloop>
      </cfoutput>
   </cfcatch>
</cftry>