CREATEODBCDATE  
説明

ODBC の日付オブジェクトを作成します。

 
戻り値

ODBC の標準日付形式の日付オブジェクト

 
カテゴリ

日付および時刻関数

 
関数のシンタックス
CreateODBCDate(date)
 
関連項目

CreateDate、CreateODBCDateTime

 
パラメータ

 
使用方法

この関数は、値の解析や確認は行いません。日付を確実に正しく入力し処理するため (たとえば、日/月/年と月/日/年とで混乱しないため)、DateFormat 関数で mm-dd-yyyy のマスクを使用して、入力した日付を 3 つの要素に分けて解析することをお勧めします。ここでは適切な範囲内の値が使用されるようにしてください。たとえば、月の値を確認するには、属性として validate = "integer" および range = "1,12" を使用します。

 
例
<h3>CreateODBCDate の例</h3>
<CFIF IsDefined("form.year")>
<p>CreateDateTime で生成された日付値 :
<CFSET yourDate = CreateDateTime(form.year, form.month, form.day, form.hour,
form.minute, form.second)>
<cfoutput>
<ul>
   <li>CreateDate で設定した形式 :#CreateDate(form.year, form.month, form.day)#
   <li>CreateDateTime で設定した形式 : 
      #CreateDateTime(form.year, form.month, form.day, form.hour, form.minute,
form.second)#
   <li>CreateODBCDate で設定した形式 :#CreateODBCDate(yourDate)#
   <li>CreateODBCDateTime で設定した形式 :#CreateODBCDateTime(yourDate)#
</ul>
<p>同じ値を、DateFormat で形式設定できます。
<ul>
   <li>CreateDate および DateFormat で設定した形式 : 
      #DateFormat(CreateDate(form.year,form.month, form.day), "mmm-dd-yyyy")#
   <li>CreateDateTime および DateFormat で設定した形式 : 
      #DateFormat(CreateDateTime(form.year, form.month, form.day, form.hour,
form.minute, form.second))#
   <li>CreateODBCDate および DateFormat で設定した形式 : 
      #DateFormat(CreateODBCDate(yourDate), "mmmm d, yyyy")#
   <li>CreateODBCDateTime および DateFormat で設定した形式 : 
      #DateFormat(CreateODBCDateTime(yourDate), "d/m/yy")#
</ul>
</cfoutput>
</CFIF>
<CFFORM ACTION="createodbcdate.cfm" METHOD="POST">
<p>年、月、および日を整数で入力します。
<PRE>
Year      <CFINPUT TYPE="Text" NAME="year" VALUE="1998" VALIDATE="integer" 
      REQUIRED="Yes">
Month      <CFINPUT TYPE="Text" NAME="month" VALUE="6" RANGE="1,12" 
      MESSAGE="月 (1 〜 12) を入力してください。" VALIDATE="integer" 
      REQUIRED="Yes">
日       <CFINPUT TYPE="Text" NAME="day" VALUE="8" RANGE="1,31" 
      MESSAGE="日 (1 〜 31) を入力してください。" VALIDATE="integer"
      REQUIRED="Yes">
時       <CFINPUT TYPE="Text" NAME="hour" VALUE="16" RANGE="0,23" 
      MESSAGE="時 (0 〜 23) を入力してください。" VALIDATE="integer"
      REQUIRED="Yes">
分       <CFINPUT TYPE="Text" NAME="minute" VALUE="12" RANGE="0,59" 
      MESSAGE="分 (0 〜 59) を入力してください。" VALIDATE="integer"
      REQUIRED="Yes">
秒       <CFINPUT TYPE="Text" NAME="second" VALUE="0" RANGE="0,59" 
      MESSAGE="秒 (0 〜 59) を入力してください。" VALIDATE="integer"
      REQUIRED="Yes">
</PRE>
<p><INPUT TYPE="Submit" NAME=""> <INPUT TYPE="RESET">
</cfform>
DATE  
日付または日付時刻オブジェクトです。値の範囲は西暦 100 〜 9999 年です。