リクエストする前に、SOAP ヘッダを Web サービスリクエストに追加します。

なし

XML 関数

ColdFusion MX 7: この関数が追加されました。

AddSOAPRequestHeader(webservice, namespace, name, value [, mustunderstand])

AddSOAPResponseHeader、GetSOAPRequest、GetSOAPRequestHeader、GetSOAPResponse、GetSOAPResponseHeader、IsSOAPRequest、『ColdFusion MX 開発ガイド』の第36章の「Web サービスの使用」 の「基本的な Web サービスの概念」

Web サービスを呼び出す前に、Web サービスの利用者が CFML コード内で使用します。

value パラメータで XML を渡す場合、ColdFusion は namespace パラメータと name パラメータを無視します。ネーム空間が必要な場合は、XML 内で定義してください。

この例は 2 つの部分で構成されています。最初の部分は Web サービス CFC です。この関数およびその他の ColdFusion SOAP 関数は、この Web サービス CFC を使用して、Web サービスとのやり取りを示します。この関数について Web サービスを実装するには、AddSOAPResponseHeader の例を参照してください。

クライアントとして次の例を実行し、AddSOAPRequestHeader 関数の動作を確認します。

<!--- CreateObject 関数内の URL がここで示されたものと異なる場合は修正して、
使用するサーバーおよび "headerservice.cfc" ファイルの場所と一致させなければ
ならないことがあります。末尾の cfinvoke タグについても同様です。 --->

<h3>AddSOAPRequestHeader の例</h3>
<cfscript>
 // Web サービスオブジェクトを作成します。
 ws = CreateObject("webservice", "http://localhost/soapheaders/headerservice.cfc?WSDL");
 
 // ユーザー名ヘッダを文字列として設定します。
 addSOAPRequestHeader(ws, "http://mynamespace/", "username", "tom", false);
 
 // パスワードヘッダを CFML XML オブジェクトとして設定します。
 doc = XmlNew();
 doc.password = XmlElemNew(doc, "http://mynamespace/", "password");
 doc.password.XmlText = "My Voice がパスワードです。";
 doc.password.XmlAttributes["xsi:type"] = "xsd:string";
 addSOAPRequestHeader(ws, "ignoredNameSpace", "ignoredName", doc);
  
 // Web サービスのオペレーションを呼び出します。
 ret = ws.echo_me("argument");
 
 // 先頭のヘッダをオブジェクト (文字列) および XML として取得します。
 header = getSOAPResponseHeader(ws, "http://www.tomj.org/myns", "returnheader");
 XMLheader = getSOAPResponseHeader(ws, "http://www.tomj.org/myns", "returnheader", true);

 // 2 番めのヘッダをオブジェクト (文字列) および XML として取得します。
 header2 =  getSOAPResponseHeader(ws, "http://www.tomj.org/myns", "returnheader2");
 XMLheader2 = getSOAPResponseHeader(ws, "http://www.tomj.org/myns", "returnheader2", 
true);
</cfscript>
<hr>
<cfoutput>
Soap Header value:#HTMLCodeFormat(header)#<br>
Soap Header XML value:#HTMLCodeFormat(XMLheader)#<br>
Soap Header 2 value:#HTMLCodeFormat(header2)#<br>
Soap Header 2 XML value:#HTMLCodeFormat(XMLheader2)#<br>
Return value:#HTMLCodeFormat(ret)#<br>
</cfoutput>
<hr>

<cfinvoke component="soapheaders.headerservice" method="echo_me" returnvariable="ret" 
in_here="hi">
</cfinvoke>
<cfoutput>Cfinvoke returned:#ret#</cfoutput>