<xsl:when>  
Définit une branche d'un élément <xsl:choose>. Il est équivalent à l'instruction case dans Java.
 
Catégorie

Subinstruction (<xsl:when> apparaît toujours comme un enfant d'un élément <xsl:choose>).
 
Attributs obligatoires
test
Contient une expression booléenne qui est évaluée. Si l'évaluation de l'expression renvoie true, les contenus de l'élément < xsl:when > sont traités ; sinon, les contenus de l'élément < xsl:when > sont ignorés.

 
Attributs facultatifs

Aucun.
 
Contenu

Un modèle XSLT.
 
Apparaît dans

L'élément <xsl:choose> uniquement.

 
Défini dans

XSLT section 9.2, Traitement conditionnel avec xsl:choose.
 
Exemple

L'exemple suivant utilise un élément <xsl:choose> et trois éléments <xsl:when> pour itérer sur un ensemble de valeurs. Il est maintenant question de générer les lignes d'une table HTML pour chaque élément <listitem> :

<?xml version="1.0"?>
<list xml:lang="en">
  <title>Albums I've bought recently:</title>
  <listitem>The Sacred Art of Dub</listitem>
  <listitem>Only the Poor Man Feel It</listitem>
  <listitem>Excitable Boy</listitem>
  <listitem xml:lang="sw">Aki Special</listitem>
  <listitem xml:lang="en-gb">Combat Rock</listitem>
  <listitem xml:lang="zu">Talking Timbuktu</listitem>
  <listitem xml:lang="jz">The Birth of the Cool</listitem>
</list>

Dans la feuille de style, les lignes de la table ont été générées avec pour couleurs d'arrière-plan mintcream, lavender, whitesmoke et papayawhip. Pour chaque élément <listitem> du document source, l'un des éléments <xsl:when> (ou bien l'élément <xsl:otherwise>) génère la couleur appropriée.

<?xml version="1.0"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">


  <xsl:output method="html"/>

  <xsl:template match="/">
    <html>
      <head>
        <title>
          <xsl:value-of select="list/title"/>
        </title>
      </head>
      <body>
        <h1><xsl:value-of select="list/title"/></h1>
        <table border="1">
          <xsl:for-each select="list/listitem">
            <tr>
              <td>
                <xsl:attribute name="bgcolor">
                  <xsl:choose>
                    <xsl:when test="@bgcolor">
                      <xsl:value-of select="@bgcolor"/>
                    </xsl:when>
                    <xsl:when test="position() mod 4 = 0">
                      <xsl:text>papayawhip</xsl:text>
                    </xsl:when>
                    <xsl:when test="position() mod 4 = 1">
                      <xsl:text>mintcream</xsl:text>
                    </xsl:when>
                    <xsl:when test="position() mod 4 = 2">
                      <xsl:text>lavender</xsl:text>
                    </xsl:when>
                    <xsl:otherwise>
                      <xsl:text>whitesmoke</xsl:text>
                    </xsl:otherwise>
                  </xsl:choose>
                </xsl:attribute>
                <xsl:value-of select="."/>
              </td>
            </tr>
          </xsl:for-each>
        </table>
      </body>
    </html>
  </xsl:template>

</xsl:stylesheet>

Une fois le document XML source traité à l'aide de la feuille de style, les résultats sont les suivants :

<html>
<head>
<META http-equiv="Content-Type" content="text/html; charset=UTF-8">
<title>Albums I've bought recently:</title>
</head>
<body>
<h1>Albums I've bought recently:</h1>
<table border="1">
<tr>
<td bgcolor="mintcream">The Sacred Art of Dub</td>
</tr>
<tr>
<td bgcolor="lavender">Only the Poor Man Feel It</td>
</tr>
<tr>
<td bgcolor="whitesmoke">Excitable Boy</td>
</tr>
<tr>
<td bgcolor="papayawhip">Aki Special</td>
</tr>
<tr>
<td bgcolor="mintcream">Combat Rock</td>
</tr>
<tr>
<td bgcolor="lavender">Talking Timbuktu</td>
</tr>
<tr>
<td bgcolor="whitesmoke">The Birth of the Cool</td>
</tr>
</table>
</body>
</html>

Tous les éléments <td> ayant pour couleur d'arrière-plan papayawhip, mintcream ou lavender ont été générés par l'un des éléments <xsl:when>.