<xsl:message>  
Envoie un message. La méthode d'envoi du message peut varier d'un processeur XSLT à l'autre, mais le message est généralement écrit dans le périphérique de sortie standard. Cet élément permet de déboguer des feuilles de style.
 
Catégorie

Instruction
 
Attributs obligatoires

Aucun.
 
Attributs facultatifs
terminate= " yes " | " no "
Si la valeur de cet attribut est yes, le processeur XSLT arrête l'exécution après avoir délivré ce message. La valeur par défaut de cet attribut est no ; si l'attribut < xsl:message > ne termine pas le processeur, le message est envoyé et le traitement se poursuit.

 
Contenu

Un modèle XSLT.
 
Apparaît dans

<xsl:message> apparaît dans un modèle.

 
Défini dans

XSLT section 13, Messages.
 
Exemple

La feuille de style suivante utilise l'élément <xsl:message> pour tracer la transformation d'un document XML. Reprenons notre liste d'albums récemment achetés :

<?xml version="1.0"?>
<list xml:lang="en">
  <title>Albums I've bought recently:</title>
  <listitem>The Sacred Art of Dub</listitem>
  <listitem>Only the Poor Man Feel It</listitem>
  <listitem>Excitable Boy</listitem>
  <listitem xml:lang="sw">Aki Special</listitem>
  <listitem xml:lang="en-gb">Combat Rock</listitem>
  <listitem xml:lang="zu">Talking Timbuktu</listitem>
  <listitem xml:lang="jz">The Birth of the Cool</listitem>
</list>

Tous les albums achetés sont répertoriés dans une table HTML dont la couleur d'arrière-plan de chaque ligne alterne entre différentes couleurs. La feuille de style utilise un élément <xsl:choose> dans un élément <xsl:attribute> pour déterminer la valeur de l'attribut bgcolor. Si un élément <listitem> donné est converti en élément HTML <tr> avec pour couleur d'arrière-plan lavender, un message d'avertissement est envoyé :

<?xml version="1.0"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

  <xsl:output method="html"/>

  <xsl:template match="/">
    <html>
      <head>
        <title>
          <xsl:value-of select="list/title"/>
        </title>
      </head>
      <body>
        <h1><xsl:value-of select="list/title"/></h1>
        <table border="1">
          <xsl:for-each select="list/listitem">
            <tr>
              <td>
                <xsl:attribute name="bgcolor">
                  <xsl:choose>
                    <xsl:when test="position() mod 4 = 0">
                      <xsl:text>papayawhip</xsl:text>
                    </xsl:when>
                    <xsl:when test="position() mod 4 = 1">
                      <xsl:text>mintcream</xsl:text>
                    </xsl:when>
                    <xsl:when test="position() mod 4 = 2">
                      <xsl:text>lavender</xsl:text>
                      <xsl:message terminate="no">
                        <xsl:text>Table row #</xsl:text>
                        <xsl:value-of select="position()"/>
                        <xsl:text> is lavender!</xsl:text>
                      </xsl:message>
                    </xsl:when>
                    <xsl:otherwise>
                      <xsl:text>whitesmoke</xsl:text>
                    </xsl:otherwise>
                  </xsl:choose>
                </xsl:attribute>
                <xsl:value-of select="."/>
              </td>
            </tr>
          </xsl:for-each>
        </table>
      </body>
    </html>
  </xsl:template>

</xsl:stylesheet>

La spécification XSLT ne définit pas la méthode d'envoi du message. L'utilisation de la feuille de style avec Xalan 2.0.1 a permis d'obtenir les résultats suivants :

file:///D:/O'Reilly/XSLT/bookSamples/AppendixA/message.xsl; Line 32; Column 51;
Table row #2 is lavender!
file:///D:/O'Reilly/XSLT/bookSamples/AppendixA/message.xsl; Line 32; Column 51;
Table row #6 is lavender!

Xalan fournit un compte-rendu sur la partie de la feuille de style ayant généré chaque message. Saxon, en revanche, vous simplifie la vie :

Table row #2 is lavender!
Table row #6 is lavender!

Par souci de diversité, voici la méthode employée par XT pour traiter l'élément <xsl:message> :

file:/D:/O'Reilly/XSLT/bookSamples/AppendixA/test4.xml:5: Table row #2 is lavender!
file:/D:/O'Reilly/XSLT/bookSamples/AppendixA/test4.xml:9: Table row #6 is lavender!

XT fournit des informations concernant la ligne du document XML source qui a généré le message.