<xsl:comment>  
Permet de créer un commentaire dans le document de sortie. Les commentaires sont parfois utilisés pour ajouter des annonces légales, des avis de non-responsabilité ou des informations relatives à la date de création du document de sortie. Une autre application pertinente de l'élément <xsl:comment> consiste à générer des définitions CSS ou un code JavaScript dans un document HTML.
 
Catégorie

Instruction
 
Attributs obligatoires

Aucun.
 
Attributs facultatifs

Aucun.
 
Contenu

Un modèle XSLT.
 
Apparaît dans

<xsl:comment> apparaît dans un modèle.
 
Défini dans

XSLT section 7.4, Création de commentaires.

 
Exemple

La feuille de style suivante génère un commentaire permettant de définir des styles CSS dans un document HTML :

<?xml version="1.0"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

  <xsl:output method="html"/>

  <xsl:template match="/">
    <html>
      <head>
        <title>XSLT and CSS Demo</title>
        <style>
          <xsl:comment>
            p.big      {font-size: 125%; font-weight: bold} 
            p.green    {color: green; font-weight: bold} 
            p.red      {color: red; font-style: italic}
          </xsl:comment>
        </style>
      </head>
      <body>
        <xsl:apply-templates select="list/title"/>
        <xsl:apply-templates select="list/listitem"/>
      </body>
    </html>
  </xsl:template>

  <xsl:template match="title">
    <p class="big"><xsl:value-of select="."/></p>
  </xsl:template>

  <xsl:template match="listitem">
    <xsl:choose>
      <xsl:when test="position() mod 2">
        <p class="green"><xsl:value-of select="."/></p>
      </xsl:when>
      <xsl:otherwise>
        <p class="red"><xsl:value-of select="."/></p>
      </xsl:otherwise>
    </xsl:choose>
  </xsl:template>
  
</xsl:stylesheet>

Cette feuille de style crée les trois styles CSS figurant dans un commentaire HTML. Cette feuille de style est appliquée au document suivant :

<?xml version="1.0"?>
<list xml:lang="en">
  <title>Albums I've bought recently:</title>
  <listitem>The Sacred Art of Dub</listitem>
  <listitem>Only the Poor Man Feel It</listitem>
  <listitem>Excitable Boy</listitem>
  <listitem xml:lang="sw">Aki Special</listitem>
  <listitem xml:lang="en-gb">Combat Rock</listitem>
  <listitem xml:lang="zu">Talking Timbuktu</listitem>
  <listitem xml:lang="jz">The Birth of the Cool</listitem>
</list>

La feuille de style applique un style CSS à l'élément <title>, puis alternera entre les deux autres styles CSS pour les éléments <listitem>. Le document HTML généré est le suivant :

<html>
<head>
<META http-equiv="Content-Type" content="text/html; charset=UTF-8">
<title>XSLT and CSS Demo</title>
<style>
<!-- 
            p.big      {font-size: 125%; font-weight: bold} 
            p.green    {color: green; font-weight: bold} 
            p.red      {color: red; font-style: italic}
          -->
</style>
</head>
<body>
<p class="big">Albums I've bought recently:</p>
<p class="green">The Sacred Art of Dub</p>
<p class="red">Only the Poor Man Feel It</p>
<p class="green">Excitable Boy</p>
<p class="red">Aki Special</p>
<p class="green">Combat Rock</p>
<p class="red">Talking Timbuktu</p>
<p class="green">The Birth of the Cool</p>
</body>
</html>

Une fois affiché, le document ressemble à laFigure A-6.

Document ayant généré des nœuds de commentaire