Fonction starts-with()  
Détermine si la première chaîne de l'argument commence par le second argument.
 
Entrées

Deux chaînes.

 
Sortie

Si la première chaîne commence par la seconde, la fonction starts-with() renvoie la valeur booléenne true ; sinon, elle renvoie la valeur false.
 
Définie dans

XPath section 4.2, Fonctions Chaîne.

 
Exemple

Le document XML utilisé est le suivant :

<?xml version="1.0"?>
<list>
  <title>A few of my favorite albums</title>
  <listitem>A Love Supreme</listitem>
  <listitem>Beat Crazy</listitem>
  <listitem>Here Come the Warm Jets</listitem>
  <listitem>Kind of Blue</listitem>
  <listitem>London Calling</listitem>
  <listitem>Remain in Light</listitem>
  <listitem>The Joshua Tree</listitem>
  <listitem>The Indestructible Beat of Soweto</listitem>
</list>

La feuille de style produit les contenus de tous les éléments <listitem> commençant par la chaîne "The" :

<?xml version="1.0"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

  <xsl:output method="text"/>

  <xsl:variable name="newline">
<xsl:text>
</xsl:text>
  </xsl:variable>

  <xsl:template match="/">
    <xsl:value-of select="$newline"/>
    <xsl:for-each select="list/listitem">
      <xsl:if test="starts-with(., 'The')">
        <xsl:value-of select="position()"/>
        <xsl:text>. </xsl:text>
        <xsl:value-of select="."/>
        <xsl:value-of select="$newline"/>
      </xsl:if>
    </xsl:for-each>
  </xsl:template>

</xsl:stylesheet>

Le résultat suivant a été généré par la feuille de style :


7. The Joshua Tree
8. The Indestructible Beat of Soweto