Fonction normalize-space()  
Supprime les espaces blancs supplémentaires de sa chaîne d'argument.
 
Entrées

Une chaîne facultative. Si l'argument a été omis, la fonction normalize-space() utilise la valeur de chaîne du nœud de contexte.

 
Sortie

La chaîne de l'argument dans laquelle les espaces blancs ont été supprimés, comme suit :

    Tous les espaces blancs de tête sont supprimés.

    Tous les espaces blancs de queue sont supprimés.

    Dans la chaîne, toutes les séquences de caractères d'espace blanc sont remplacées par un espace simple.
 
Définie dans

XPath section 4.2, Fonctions Chaîne.
 
Exemple

Le court exemple suivant montre le fonctionnement de la fonction normalize-space() :

<?xml version="1.0"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

  <xsl:output method="text"/>

  <xsl:variable name="newline">
<xsl:text>
</xsl:text>
  </xsl:variable>


  <xsl:variable name="testString">
    <xsl:text>                 This
is


a string
with lots of


whitespace.

</xsl:text>
    </xsl:variable>

  <xsl:template match="/">
    <xsl:value-of select="$newline"/>
    <xsl:text>Tests of the normalize-space() function:</xsl:text>

    <xsl:value-of select="$newline"/>
    <xsl:value-of select="$newline"/>
    <xsl:text>   normalize-space('       Hello,            World!')="</xsl:text>
    <xsl:value-of select="normalize-space('       Hello,            World!')"/>
    <xsl:text>"</xsl:text>
    <xsl:value-of select="$newline"/>
    <xsl:text>   normalize-space($newline)="</xsl:text>
    <xsl:value-of select="normalize-space($newline)"/>
    <xsl:text>"</xsl:text>
    <xsl:value-of select="$newline"/>
    <xsl:text>   normalize-space($testString)="</xsl:text>
    <xsl:value-of select="normalize-space($testString)"/>
    <xsl:text>"</xsl:text>
    <xsl:value-of select="$newline"/>
  </xsl:template>

</xsl:stylesheet>

La feuille de style génère la sortie suivante :


Tests of the normalize-space() function:

   normalize-space('       Hello,            World!')="Hello, World!"
   normalize-space($newline)="
   normalize-space($testString)="This is a string with lots of whitespace."